recipes-bsp: Add u-boot-compulab-fw-utils

Signed-off-by: Valentin Raevsky <valentin@compulab.co.il>

recipes-bsp/u-boot/u-boot-compulab-fw-utils_2020.04.bb

@@ -0,0 +1,60 @@
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+SECTION = "bootloaders"
+DEPENDS = "flex-native bison-native mtd-utils"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+UBOOT_SRC = "git://source.codeaurora.org/external/imx/uboot-imx.git;protocol=https"
+SRCBRANCH = "imx_v2020.04_5.4.24_2.1.0"
+SRC_URI = "${UBOOT_SRC};branch=${SRCBRANCH}"
+SRCREV = "4979a99482f7e04a3c1f4fb55e3182395ee8f710"
+
+S = "${WORKDIR}/git"
+
+require u-boot-compulab.inc
+
+SRC_URI_append += "\
+	file://cl_setenv \
+"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'HOSTCC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+	oe_runmake ${UBOOT_MACHINE}
+	oe_runmake envtools
+}
+
+do_install () {
+	install -d ${D}${base_sbindir}
+	install -d ${D}${sysconfdir}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+	install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+	install -d ${D}${bindir_cross}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"
+
+do_install_append () {
+	install -d ${D}/sbin
+	install -m 0755 ${WORKDIR}/cl_setenv ${D}/sbin/
+}
+
+RDEPENDS_${PN} += "bash"
+
+FILES_${PN} = "/sbin/* /etc/*"
+
+RPROVIDES_${PN} += "u-boot-fw-utils"