mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-10-05 22:02:55 +01:00
Chandler Carruthandjosh11b
7871237c15
Implements proposal #7016: `self` moves from the deduced implicit list (`fn F[self: Self]()`) to the front of the explicit list. Its type may be written explicitly (`fn F(self: Self)`) or omitted, in which case it defaults to `Self` (`fn F(self)`, `fn F(ref self)`); `self` in the implicit list is rejected. Throughout checking, `self` is modeled as the first explicit parameter. Because a method is just a function whose first parameter is `self`, it can also be called as an ordinary function with the receiver passed explicitly (`Type.M(obj, ...)`), not only as `obj.M(...)`. A new `SemIR::CallArgParamPatterns` helper chooses the parameters matched against the explicit arguments, excluding a leading `self` only when it is supplied as a method-call receiver; arity checking, conversion, and generic deduction use it. The resulting SemIR and lowering are unchanged: `self` is still `call_param0`, and witnesses, thunks, and vtables are unaffected. An omitted `self` type is parsed as a `SelfBindingPattern` node with no type expression; checking synthesizes the `Self` type so it behaves exactly like `self: Self`. However, the exact spelling used must match between a forward declaration and a definition, following #3763's rules around declaration matching. Generated functions, thunks, and C++ interop import/export build `self` as the first explicit parameter, and the `self`-type override (e.g. Derived->Base for a virtual override) applies to the explicit `self`. Placement is validated by new diagnostics: `SelfInImplicitParamList`, `SelfNotFirstParam`, and `SelfOutsideParamList`. The benchmark source generator and the documentation adopt the `(self)` shorthand; the prelude, the examples, and the test data are migrated in the following commits. Assisted-by: Claude Code with Claude Opus 4.7 --------- Co-authored-by: josh11b <15258583+josh11b@users.noreply.github.com>
85 lines
2.1 KiB
Plaintext
85 lines
2.1 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
// https://adventofcode.com/2024/day/11
|
|
|
|
import Core library "io";
|
|
import Core library "range";
|
|
|
|
import library "day11_common";
|
|
import library "io_utils";
|
|
|
|
class Digits {
|
|
impl as Core.UnformedInit {}
|
|
|
|
fn Make() -> Digits {
|
|
returned var me: Digits;
|
|
for (digit: i32 in Core.Range(10)) {
|
|
for (depth: i32 in Core.Range(75)) {
|
|
me.count[digit][depth] = 0;
|
|
}
|
|
}
|
|
return var;
|
|
}
|
|
|
|
fn Print(self, max_depth: i32) {
|
|
for (digit: i32 in Core.Range(10)) {
|
|
Core.PrintChar(((digit + 0x30) as u8) as char);
|
|
Core.PrintChar(':');
|
|
for (depth: i32 in Core.Range(max_depth)) {
|
|
Core.PrintChar(' ');
|
|
PrintIntNoNewline(self.count[digit][depth]);
|
|
}
|
|
Core.PrintChar('\n');
|
|
}
|
|
Core.PrintChar('\n');
|
|
}
|
|
|
|
var count: array(array(i64, 75), 10);
|
|
}
|
|
|
|
fn ReduceToDigits(n: i64, depth: i32, multiplicity: i64, digits: Digits*) -> i64 {
|
|
if (n == -1) { return 0; }
|
|
if (depth == 0) { return multiplicity; }
|
|
if (n < 10) {
|
|
let count: i64* = &digits->count[n as i32][depth - 1];
|
|
*count += multiplicity;
|
|
return 0;
|
|
}
|
|
let next: (i64, i64) = Next(n);
|
|
return ReduceToDigits(next.0, depth - 1, multiplicity, digits) +
|
|
ReduceToDigits(next.1, depth - 1, multiplicity, digits);
|
|
}
|
|
|
|
fn Run() {
|
|
let max_depth: i32 = 75;
|
|
var total: i64 = 0;
|
|
var digits: Digits = Digits.Make();
|
|
|
|
var n: i64;
|
|
while (ReadInt(ref n)) {
|
|
total += ReduceToDigits(n, max_depth, 1, &digits);
|
|
// PrintInt(total);
|
|
// digits.Print(max_depth - 1);
|
|
SkipSpaces();
|
|
}
|
|
|
|
var depth: i32 = max_depth - 1;
|
|
while (depth >= 0) {
|
|
// PrintInt(total);
|
|
// digits.Print(depth);
|
|
for (digit: i32 in Core.Range(10)) {
|
|
let m: i64 = digits.count[digit][depth];
|
|
if (m > 0) {
|
|
let next: (i64, i64) = Next(digit as i64);
|
|
total += ReduceToDigits(next.0, depth, m, &digits) +
|
|
ReduceToDigits(next.1, depth, m, &digits);
|
|
}
|
|
}
|
|
--depth;
|
|
}
|
|
|
|
PrintInt(total);
|
|
}
|