mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-10-05 21:51:12 +01:00
Chandler Carruthandjosh11b
7871237c15
Implements proposal #7016: `self` moves from the deduced implicit list (`fn F[self: Self]()`) to the front of the explicit list. Its type may be written explicitly (`fn F(self: Self)`) or omitted, in which case it defaults to `Self` (`fn F(self)`, `fn F(ref self)`); `self` in the implicit list is rejected. Throughout checking, `self` is modeled as the first explicit parameter. Because a method is just a function whose first parameter is `self`, it can also be called as an ordinary function with the receiver passed explicitly (`Type.M(obj, ...)`), not only as `obj.M(...)`. A new `SemIR::CallArgParamPatterns` helper chooses the parameters matched against the explicit arguments, excluding a leading `self` only when it is supplied as a method-call receiver; arity checking, conversion, and generic deduction use it. The resulting SemIR and lowering are unchanged: `self` is still `call_param0`, and witnesses, thunks, and vtables are unaffected. An omitted `self` type is parsed as a `SelfBindingPattern` node with no type expression; checking synthesizes the `Self` type so it behaves exactly like `self: Self`. However, the exact spelling used must match between a forward declaration and a definition, following #3763's rules around declaration matching. Generated functions, thunks, and C++ interop import/export build `self` as the first explicit parameter, and the `self`-type override (e.g. Derived->Base for a virtual override) applies to the explicit `self`. Placement is validated by new diagnostics: `SelfInImplicitParamList`, `SelfNotFirstParam`, and `SelfOutsideParamList`. The benchmark source generator and the documentation adopt the `(self)` shorthand; the prelude, the examples, and the test data are migrated in the following commits. Assisted-by: Claude Code with Claude Opus 4.7 --------- Co-authored-by: josh11b <15258583+josh11b@users.noreply.github.com>
71 lines
2.0 KiB
Plaintext
71 lines
2.0 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
package Core library "prelude/iterate";
|
|
|
|
export import library "prelude/copy";
|
|
export import library "prelude/destroy";
|
|
export import library "prelude/types";
|
|
export import library "prelude/operators";
|
|
|
|
interface Iterate {
|
|
// TODO: Support iterating ranges of non-copyable values.
|
|
let ElementType:! Copy & Destroy;
|
|
let CursorType:! Destroy;
|
|
fn NewCursor(self) -> CursorType;
|
|
fn Next(self, cursor: CursorType*) -> Optional(ElementType);
|
|
}
|
|
|
|
impl forall [T:! Copy & Destroy, N:! IntLiteral]
|
|
array(T, N) as Iterate
|
|
where .ElementType = T and .CursorType = i32 {
|
|
fn NewCursor(unused self) -> i32 { return 0; }
|
|
fn Next(self, cursor: i32*) -> Optional(T) {
|
|
if (*cursor < N) {
|
|
++*cursor;
|
|
return Optional(T).Some(self[*cursor - 1]);
|
|
} else {
|
|
return Optional(T).None();
|
|
}
|
|
}
|
|
}
|
|
|
|
interface CppRangeForIterate {
|
|
let Iterator:! type;
|
|
let Sentinel:! type;
|
|
|
|
// TODO: self must be ref-qualified
|
|
fn Begin(self) -> Iterator;
|
|
fn End(self) -> Sentinel;
|
|
}
|
|
|
|
impl forall [
|
|
R:! CppRangeForIterate where
|
|
.Iterator impls Copy & Destroy & CppUnsafeDeref & Inc & EqWith(.Sentinel) and
|
|
.Iterator.(CppUnsafeDeref.Result) impls Copy & Destroy and
|
|
.Sentinel impls Copy & Destroy
|
|
]
|
|
R as Iterate
|
|
where
|
|
.ElementType = R.Iterator.(CppUnsafeDeref.Result) and
|
|
.CursorType = (R.Iterator, R.Sentinel)
|
|
{
|
|
alias ElementType = R.Iterator.(CppUnsafeDeref.Result);
|
|
|
|
fn NewCursor(self) -> (R.Iterator, R.Sentinel) {
|
|
return (self.Begin(), self.End());
|
|
}
|
|
|
|
fn Next(unused self, cursor: (R.Iterator, R.Sentinel)*) -> Optional(ElementType) {
|
|
if (cursor->0 != cursor->1) {
|
|
returned var result: Optional(ElementType) =
|
|
Optional(ElementType).Some(cursor->0.(CppUnsafeDeref.Op)());
|
|
++cursor->0;
|
|
return var;
|
|
} else {
|
|
return Optional(ElementType).None();
|
|
}
|
|
}
|
|
}
|