mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-09-24 18:50:09 +01:00
Chandler Carruth
8be274cf60
Implement the toolchain side of proposal #7254, removing the `:!` binding syntax for generic and template parameters in favor of the keywords `generic`, `template`, and `runtime` plus contextual defaults for phase. For valid programs this is semantics-preserving: each binding resolves to the same phase, and produces the same SemIR, as it did under `:!`/`:`. The parser derives a binding's phase from its syntactic context plus any explicit phase keyword; new diagnostics and error recovery for misused keywords are described below. Implementation details for each component: - Lexer: remove the `:!` (`ColonExclaim`) token, move its virtual parse-node budget onto `:`, and add the `generic` and `runtime` keywords. - Parser: thread a `BindingContext` (`ExplicitParam`, `DeducedParam`, or `CompileTimeEntityParam`) from declaration introducers down through parameter lists to each binding pattern, using a one-token lookahead to distinguish a name-qualifier parameter list from a declaration's own final list. Parameters of a compile-time entity (`class`, `interface`, `constraint`, `choice`, `alias`, `export`, `namespace`) and deduced `[]` parameters default to checked generic; explicit function parameters and local bindings default to runtime. `HandleBindingPattern` resolves the phase from that context plus the keyword: a `generic` keyword needs no node of its own (the phase is carried by the binding's node kind), while a `runtime` keyword is preserved as a `RuntimeBindingName` node so `check` can name it in a diagnostic. A phase keyword that is merely redundant with the contextual default is diagnosed here, without invalidating the parse tree. - Check: a phase keyword that is invalid for its context (for example `runtime` on a checked-generic parameter) is diagnosed here, and recovers by building an error binding that still introduces the name so that later uses of it do not produce cascading errors. The removed `:!` syntax is now rejected as an ordinary parse error. The `form`/`:?`/`->?` ("extended types") portion of proposal #7254 is left for a separate change. Assisted-by: Claude Code
62 lines
1.9 KiB
Plaintext
62 lines
1.9 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
library "sort";
|
|
|
|
interface Ordered {
|
|
// extend require impls Core.OrderedWith(Self);
|
|
fn Less(self, other: Self) -> bool;
|
|
fn LessOrEquivalent(self, other: Self) -> bool;
|
|
fn Greater(self, other: Self) -> bool;
|
|
fn GreaterOrEquivalent(self, other: Self) -> bool;
|
|
}
|
|
|
|
impl i32 as Ordered {
|
|
fn Less(self, other: Self) -> bool { return self < other; }
|
|
fn LessOrEquivalent(self, other: Self) -> bool { return self <= other; }
|
|
fn Greater(self, other: Self) -> bool { return self > other; }
|
|
fn GreaterOrEquivalent(self, other: Self) -> bool { return self >= other; }
|
|
}
|
|
|
|
fn Swap[T: Core.Copy & Core.Destroy](ref from: T, ref to: T) {
|
|
var tmp: T = from;
|
|
from = to;
|
|
to = tmp;
|
|
}
|
|
|
|
fn Partition
|
|
[T: Core.Copy & Core.Destroy & Ordered, N: Core.IntLiteral]
|
|
(ref a: array(T, N), from_in: i32, to_in: i32) -> i32 {
|
|
var pivot_index: i32 = from_in;
|
|
let pivot: T = a[pivot_index];
|
|
var from: i32 = from_in + 1;
|
|
var to: i32 = to_in;
|
|
while (from < to) {
|
|
// TODO: if (a[from] <= pivot) {
|
|
if (a[from].(Ordered.LessOrEquivalent)(pivot)) {
|
|
++from;
|
|
// TODO: } else if ((*p)[to - 1] > pivot) {
|
|
} else if (a[to - 1].(Ordered.Greater)(pivot)) {
|
|
--to;
|
|
} else {
|
|
// Element at `from` is > pivot, and
|
|
// element at `to - 1` is <= pivot.
|
|
Swap(ref a[from], ref a[to - 1]);
|
|
++from;
|
|
--to;
|
|
}
|
|
}
|
|
Swap(ref a[pivot_index], ref a[from - 1]);
|
|
return from - 1;
|
|
}
|
|
|
|
fn Quicksort
|
|
[T: Core.Copy & Core.Destroy & Ordered, N: Core.IntLiteral]
|
|
(ref a: array(T, N), from: i32, to: i32) {
|
|
if (from + 1 >= to) { return; }
|
|
var pivot: i32 = Partition(ref a, from, to);
|
|
Quicksort(ref a, from, pivot);
|
|
Quicksort(ref a, pivot + 1, to);
|
|
}
|