mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-09-24 13:40:11 +01:00
Chandler Carruth
8be274cf60
Implement the toolchain side of proposal #7254, removing the `:!` binding syntax for generic and template parameters in favor of the keywords `generic`, `template`, and `runtime` plus contextual defaults for phase. For valid programs this is semantics-preserving: each binding resolves to the same phase, and produces the same SemIR, as it did under `:!`/`:`. The parser derives a binding's phase from its syntactic context plus any explicit phase keyword; new diagnostics and error recovery for misused keywords are described below. Implementation details for each component: - Lexer: remove the `:!` (`ColonExclaim`) token, move its virtual parse-node budget onto `:`, and add the `generic` and `runtime` keywords. - Parser: thread a `BindingContext` (`ExplicitParam`, `DeducedParam`, or `CompileTimeEntityParam`) from declaration introducers down through parameter lists to each binding pattern, using a one-token lookahead to distinguish a name-qualifier parameter list from a declaration's own final list. Parameters of a compile-time entity (`class`, `interface`, `constraint`, `choice`, `alias`, `export`, `namespace`) and deduced `[]` parameters default to checked generic; explicit function parameters and local bindings default to runtime. `HandleBindingPattern` resolves the phase from that context plus the keyword: a `generic` keyword needs no node of its own (the phase is carried by the binding's node kind), while a `runtime` keyword is preserved as a `RuntimeBindingName` node so `check` can name it in a diagnostic. A phase keyword that is merely redundant with the contextual default is diagnosed here, without invalidating the parse tree. - Check: a phase keyword that is invalid for its context (for example `runtime` on a checked-generic parameter) is diagnosed here, and recovers by building an error binding that still introduces the name so that later uses of it do not produce cascading errors. The removed `:!` syntax is now rejected as an ordinary parse error. The `form`/`:?`/`->?` ("extended types") portion of proposal #7254 is left for a separate change. Assisted-by: Claude Code
72 lines
1.8 KiB
Plaintext
72 lines
1.8 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
package Core library "prelude/copy";
|
|
|
|
// Copying an object, which is a conversion from a value representation to an
|
|
// initializing representation.
|
|
interface Copy {
|
|
fn Op(self) -> Self;
|
|
}
|
|
|
|
private fn MakeBool() -> type = "bool.make_type";
|
|
private alias Bool = MakeBool();
|
|
private fn MakeCharLiteral() -> type = "char_literal.make_type";
|
|
private alias CharLiteral = MakeCharLiteral();
|
|
private fn MakeFloatLiteral() -> type = "float_literal.make_type";
|
|
private alias FloatLiteral = MakeFloatLiteral();
|
|
private fn MakeIntLiteral() -> type = "int_literal.make_type";
|
|
private alias IntLiteral = MakeIntLiteral();
|
|
|
|
impl forall [T: Copy] const T as Copy {
|
|
fn Op(self) -> Self { return (self as T).(Copy.Op)() as const T; }
|
|
}
|
|
|
|
impl Bool as Copy {
|
|
fn Op(self) -> Self = "primitive_copy";
|
|
}
|
|
|
|
impl CharLiteral as Copy {
|
|
fn Op(self) -> Self = "primitive_copy";
|
|
}
|
|
|
|
impl FloatLiteral as Copy {
|
|
fn Op(self) -> Self = "primitive_copy";
|
|
}
|
|
|
|
impl IntLiteral as Copy {
|
|
fn Op(self) -> Self = "primitive_copy";
|
|
}
|
|
|
|
impl type as Copy {
|
|
fn Op(self) -> Self = "primitive_copy";
|
|
}
|
|
|
|
impl forall [T: type] T* as Copy {
|
|
fn Op(self) -> Self = "primitive_copy";
|
|
}
|
|
|
|
// TODO: Implement tuple copy as a variadic generic impl.
|
|
impl () as Copy {
|
|
fn Op(self) -> Self = "no_op";
|
|
}
|
|
|
|
impl forall [T: Copy] (T,) as Copy {
|
|
fn Op(self) -> Self {
|
|
return (self.0.Op(),);
|
|
}
|
|
}
|
|
|
|
impl forall [T: Copy, U: Copy] (T, U) as Copy {
|
|
fn Op(self) -> Self {
|
|
return (self.0.Op(), self.1.Op());
|
|
}
|
|
}
|
|
|
|
impl forall [T: Copy, U: Copy, V: Copy] (T, U, V) as Copy {
|
|
fn Op(self) -> Self {
|
|
return (self.0.Op(), self.1.Op(), self.2.Op());
|
|
}
|
|
}
|