mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-09-24 22:02:23 +01:00
Richard Smith
212188a922
Allow interleaving of STDOUT and STDERR check lines. Put STDOUT lines after the line they're attached to, and STDERR lines before. If no STDOUT check line is attached to any line, then put them all at the end of the file instead. This is intended to better handle the case where stdout contains unreplaced mentions of line numbers, and also reflects that stdout is typically a consequence of the test rather than commentary on it, so placing it after the test seems likely to read better.
50 lines
1.1 KiB
Plaintext
50 lines
1.1 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
//
|
|
// AUTOUPDATE
|
|
|
|
package ExplorerTest api;
|
|
|
|
interface Number {
|
|
fn Zero() -> Self;
|
|
fn Add[self: Self](other: Self) -> Self;
|
|
}
|
|
|
|
class Point(T:! Number) {
|
|
var x: T;
|
|
var y: T;
|
|
}
|
|
|
|
impl i32 as Number {
|
|
fn Zero() -> i32 { return 0; }
|
|
fn Add[self: i32](other: i32) -> i32 { return self + other; }
|
|
}
|
|
|
|
impl forall [U:! Number] Point(U) as Number {
|
|
fn Zero() -> Point(U) { return {.x = U.Zero(), .y = U.Zero() }; }
|
|
fn Add[self: Point(U)](other: Point(U)) -> Point(U) {
|
|
return {.x = self.x.Add(other.x), .y = self.y.Add(other.y)};
|
|
}
|
|
}
|
|
|
|
fn Sum[E:! Number](x: E, y: E) -> E {
|
|
var total: E = E.Zero();
|
|
total = total.Add(x);
|
|
total = total.Add(y);
|
|
return total;
|
|
}
|
|
|
|
fn SumPoints[E:! Number](p: Point(E), q: Point(E)) -> Point(E) {
|
|
return Sum(p, q);
|
|
}
|
|
|
|
fn Main() -> i32 {
|
|
var p: Point(i32) = {.x = 1, .y = 2};
|
|
var q: Point(i32) = {.x = 4, .y = 3};
|
|
var r: Point(i32) = SumPoints(p, q);
|
|
return r.x - r.y;
|
|
}
|
|
|
|
// CHECK:STDOUT: result: 0
|