mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-09-27 22:02:33 +01:00
Jon Ross-Perkins
9fefef162f
Use the diagnostic kind printing in #4425 to catch when we have diagnostics with no tests. This merges a couple other use-cases of filegroup manifests into a common rule. Note I do add a few tests for things, and also some things are _actually_ unit tested (just not in the file_test structure). But I stopped when I realized that dealing with merge conflicts is going to be a pain. I might end up reverting test changes (as part of merge conflict resolution) and doing narrow test additions in a separate PR, after both this and #4425 are merged.
62 lines
1.8 KiB
Python
62 lines
1.8 KiB
Python
# Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
# Exceptions. See /LICENSE for license information.
|
|
# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
"""Rules for building file tests.
|
|
|
|
file_test uses the tests_as_input_file rule to transform test dependencies into
|
|
a file which can be accessed as a list. This avoids long argument parsing.
|
|
"""
|
|
|
|
load("@rules_cc//cc:defs.bzl", "cc_test")
|
|
load("//bazel/manifest:defs.bzl", "manifest")
|
|
|
|
def file_test(
|
|
name,
|
|
tests,
|
|
data = [],
|
|
args = [],
|
|
prebuilt_binary = None,
|
|
**kwargs):
|
|
"""Generates tests using the file_test base.
|
|
|
|
There will be one main test using `name` that can be sharded, and includes
|
|
all files. Additionally, per-file tests will be generated as
|
|
`name.file_path`; these per-file tests will be manual.
|
|
|
|
Args:
|
|
name: The base name of the tests.
|
|
tests: The list of test files to use as data, typically a glob.
|
|
data: Passed to cc_test.
|
|
args: Passed to cc_test.
|
|
prebuilt_binary: If set, specifies a prebuilt test binary to use instead
|
|
of building a new one.
|
|
**kwargs: Passed to cc_test.
|
|
"""
|
|
|
|
# Ensure tests are always a filegroup for tests_as_input_file_rule.
|
|
tests_file = "{0}.tests".format(name)
|
|
manifest(
|
|
name = tests_file,
|
|
srcs = tests,
|
|
testonly = 1,
|
|
)
|
|
args = ["--test_targets_file=$(rootpath :{0})".format(tests_file)] + args
|
|
data = [":" + tests_file] + tests + data
|
|
|
|
if prebuilt_binary:
|
|
native.sh_test(
|
|
name = name,
|
|
srcs = [prebuilt_binary],
|
|
data = data,
|
|
args = args,
|
|
**kwargs
|
|
)
|
|
else:
|
|
cc_test(
|
|
name = name,
|
|
data = data,
|
|
args = args,
|
|
**kwargs
|
|
)
|