mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-10-05 20:51:16 +01:00
Chandler Carruthandjosh11b
7871237c15
Implements proposal #7016: `self` moves from the deduced implicit list (`fn F[self: Self]()`) to the front of the explicit list. Its type may be written explicitly (`fn F(self: Self)`) or omitted, in which case it defaults to `Self` (`fn F(self)`, `fn F(ref self)`); `self` in the implicit list is rejected. Throughout checking, `self` is modeled as the first explicit parameter. Because a method is just a function whose first parameter is `self`, it can also be called as an ordinary function with the receiver passed explicitly (`Type.M(obj, ...)`), not only as `obj.M(...)`. A new `SemIR::CallArgParamPatterns` helper chooses the parameters matched against the explicit arguments, excluding a leading `self` only when it is supplied as a method-call receiver; arity checking, conversion, and generic deduction use it. The resulting SemIR and lowering are unchanged: `self` is still `call_param0`, and witnesses, thunks, and vtables are unaffected. An omitted `self` type is parsed as a `SelfBindingPattern` node with no type expression; checking synthesizes the `Self` type so it behaves exactly like `self: Self`. However, the exact spelling used must match between a forward declaration and a definition, following #3763's rules around declaration matching. Generated functions, thunks, and C++ interop import/export build `self` as the first explicit parameter, and the `self`-type override (e.g. Derived->Base for a virtual override) applies to the explicit `self`. Placement is validated by new diagnostics: `SelfInImplicitParamList`, `SelfNotFirstParam`, and `SelfOutsideParamList`. The benchmark source generator and the documentation adopt the `(self)` shorthand; the prelude, the examples, and the test data are migrated in the following commits. Assisted-by: Claude Code with Claude Opus 4.7 --------- Co-authored-by: josh11b <15258583+josh11b@users.noreply.github.com>
113 lines
2.4 KiB
Plaintext
113 lines
2.4 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
// https://adventofcode.com/2024/day/6
|
|
|
|
library "day6_common";
|
|
|
|
import Core library "io";
|
|
import library "io_utils";
|
|
|
|
// TODO: Use a choice type.
|
|
fn Empty() -> i8 { return 0; }
|
|
fn Visited() -> i8 { return 1; }
|
|
fn Wall() -> i8 { return 2; }
|
|
|
|
class Maze {
|
|
impl as Core.UnformedInit {}
|
|
|
|
fn Read() -> Maze {
|
|
returned var me: Maze;
|
|
|
|
var y: i32 = 0;
|
|
while (y < 130) {
|
|
var x: i32 = 0;
|
|
while (x < 130) {
|
|
var cell: i32 = Core.ReadChar();
|
|
if (cell == 0x23) {
|
|
me.data[x][y] = Wall();
|
|
} else if (cell == 0x5E) {
|
|
// TODO: Handle other starting directions?
|
|
me.data[x][y] = Visited();
|
|
me.loc = (x, y);
|
|
me.dir = (0, -1);
|
|
} else {
|
|
me.data[x][y] = Empty();
|
|
}
|
|
++x;
|
|
}
|
|
SkipNewline();
|
|
++y;
|
|
}
|
|
return var;
|
|
}
|
|
|
|
fn Copy(self) -> Maze {
|
|
returned var copy: Maze;
|
|
var y: i32 = 0;
|
|
while (y < 130) {
|
|
var x: i32 = 0;
|
|
while (x < 130) {
|
|
copy.data[x][y] = self.data[x][y];
|
|
++x;
|
|
}
|
|
++y;
|
|
}
|
|
copy.loc = self.loc;
|
|
copy.dir = self.dir;
|
|
return var;
|
|
}
|
|
|
|
fn Step(ref self) -> bool {
|
|
let x: i32 = self.loc.0 + self.dir.0;
|
|
let y: i32 = self.loc.1 + self.dir.1;
|
|
if (x < 0 or x >= 130 or y < 0 or y >= 130) {
|
|
return false;
|
|
}
|
|
if (self.data[x][y] == Wall()) {
|
|
// TODO: Should this work?
|
|
// self.dir = (-self.dir.1, self.dir.0);
|
|
let d: (i32, i32) = self.dir;
|
|
self.dir = (-d.1, d.0);
|
|
} else {
|
|
self.loc = (x, y);
|
|
self.data[x][y] = Visited();
|
|
}
|
|
return true;
|
|
}
|
|
|
|
fn AddObstacle(ref self) -> bool {
|
|
let x: i32 = self.loc.0 + self.dir.0;
|
|
let y: i32 = self.loc.1 + self.dir.1;
|
|
if (x < 0 or x >= 130 or y < 0 or y >= 130) {
|
|
return false;
|
|
}
|
|
if (self.data[x][y] != Empty()) {
|
|
return false;
|
|
}
|
|
self.data[x][y] = Wall();
|
|
return true;
|
|
}
|
|
|
|
fn CountVisited(self) -> i32 {
|
|
var total: i32 = 0;
|
|
var y: i32 = 0;
|
|
while (y < 130) {
|
|
var x: i32 = 0;
|
|
while (x < 130) {
|
|
if (self.data[x][y] == Visited()) {
|
|
++total;
|
|
}
|
|
++x;
|
|
}
|
|
++y;
|
|
}
|
|
return total;
|
|
}
|
|
|
|
var data: array(array(i8, 130), 130);
|
|
var loc: (i32, i32);
|
|
var dir: (i32, i32);
|
|
}
|