mirror of
https://github.com/carbon-language/carbon-lang.git
synced 2026-09-24 20:30:14 +01:00
Chandler Carruthandjosh11b
7871237c15
Implements proposal #7016: `self` moves from the deduced implicit list (`fn F[self: Self]()`) to the front of the explicit list. Its type may be written explicitly (`fn F(self: Self)`) or omitted, in which case it defaults to `Self` (`fn F(self)`, `fn F(ref self)`); `self` in the implicit list is rejected. Throughout checking, `self` is modeled as the first explicit parameter. Because a method is just a function whose first parameter is `self`, it can also be called as an ordinary function with the receiver passed explicitly (`Type.M(obj, ...)`), not only as `obj.M(...)`. A new `SemIR::CallArgParamPatterns` helper chooses the parameters matched against the explicit arguments, excluding a leading `self` only when it is supplied as a method-call receiver; arity checking, conversion, and generic deduction use it. The resulting SemIR and lowering are unchanged: `self` is still `call_param0`, and witnesses, thunks, and vtables are unaffected. An omitted `self` type is parsed as a `SelfBindingPattern` node with no type expression; checking synthesizes the `Self` type so it behaves exactly like `self: Self`. However, the exact spelling used must match between a forward declaration and a definition, following #3763's rules around declaration matching. Generated functions, thunks, and C++ interop import/export build `self` as the first explicit parameter, and the `self`-type override (e.g. Derived->Base for a virtual override) applies to the explicit `self`. Placement is validated by new diagnostics: `SelfInImplicitParamList`, `SelfNotFirstParam`, and `SelfOutsideParamList`. The benchmark source generator and the documentation adopt the `(self)` shorthand; the prelude, the examples, and the test data are migrated in the following commits. Assisted-by: Claude Code with Claude Opus 4.7 --------- Co-authored-by: josh11b <15258583+josh11b@users.noreply.github.com>
61 lines
1.5 KiB
Plaintext
61 lines
1.5 KiB
Plaintext
// Part of the Carbon Language project, under the Apache License v2.0 with LLVM
|
|
// Exceptions. See /LICENSE for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
|
|
// https://adventofcode.com/2024/day/7
|
|
|
|
library "day7_common";
|
|
|
|
import Core library "io";
|
|
import library "io_utils";
|
|
|
|
fn Concat(a_val: i64, b_val: i64) -> i64 {
|
|
var a: i64 = a_val;
|
|
var b: i64 = b_val;
|
|
if (b == 0) {
|
|
return a * 10;
|
|
}
|
|
while (b != 0) {
|
|
a *= 10;
|
|
b /= 10;
|
|
}
|
|
return a + b_val;
|
|
}
|
|
|
|
class Equation {
|
|
impl as Core.UnformedInit {}
|
|
|
|
fn Read() -> Equation {
|
|
returned var me: Equation;
|
|
me.num_operands = 0;
|
|
ReadInt(ref me.result);
|
|
ConsumeChar(':');
|
|
while (ConsumeChar(' ')) {
|
|
ReadInt(ref me.operands[me.num_operands]);
|
|
++me.num_operands;
|
|
}
|
|
while (SkipNewline()) {}
|
|
return var;
|
|
}
|
|
|
|
fn SolveFrom(self, start: i32, value: i64, concat: bool) -> bool {
|
|
if (value > self.result) {
|
|
return false;
|
|
}
|
|
if (start == self.num_operands) {
|
|
return value == self.result;
|
|
}
|
|
return self.SolveFrom(start + 1, value + self.operands[start], concat) or
|
|
self.SolveFrom(start + 1, value * self.operands[start], concat) or
|
|
(concat and self.SolveFrom(start + 1, Concat(value, self.operands[start]), true));
|
|
}
|
|
|
|
fn Solve(self, concat: bool) -> bool {
|
|
return self.SolveFrom(1, self.operands[0], concat);
|
|
}
|
|
|
|
var operands: array(i64, 16);
|
|
var num_operands: i32;
|
|
var result: i64;
|
|
}
|